/* #line 1  "default.lcf.h" /* stack depth 0 */
/* #line 1  "boot.h"    /* stack depth 1 */
/* #line 34 "default.lcf.h" /* stack depth 0 */

// MEMORY directive 
// - Delineates areas in the target platform�fs memory map.
// - Associates a name for each of these areas. 

MEMORY {
text : origin = 0x80004000
}

// SECTIONS directive 
// - Define sections in the linker�fs output file.
// - Specifies in which memory area on the target platform a section 
//   in the output file should be loaded at runtime.

SECTIONS {

// GROUP directive 
// - Organizes objects.

GROUP:{
.init ALIGN(0x20):{}      // Initialization executable code from the runtime library
extab ALIGN(0x20):{}      // C++ exception tables
extabindex ALIGN(0x20):{} // C++ exception tables
.text ALIGN(0x20):{}      // Application code
.ctors ALIGN(0x20):{}     // C++ constructors and Altivec vector constructors
.dtors ALIGN(0x20):{}     // C++ destructors
.rodata ALIGN(0x20):{}    // Literal values and initialization values
.data ALIGN(0x20):{}      // Initialized global data
.sdata ALIGN(0x20):{}     // Initialized small global data
.sbss ALIGN(0x20):{}      // Uninitialized global small data
.sdata2 ALIGN(0x20):{}    // Initialized global small data defined with the const keyword
.sbss2 ALIGN(0x20):{}     // Uninitialized global constant small data defined with the const keyword
.bss ALIGN(0x20):{}       // Uninitialized global data
.stack ALIGN(0x100):{}    // Stack data
} > text

_stack_addr = (_f_bss + SIZEOF(.bss) + 65536 + 0x7) & ~0x7; // Top of the stack
_stack_end = _f_bss + SIZEOF(.bss);                         // Bottom of the stack

_db_stack_addr = (_stack_addr + 0x2000); // Top of the stack for a debugger
_db_stack_end = _stack_addr;             // Bottom of the stack for a debugger

}
FORCEACTIVE { 
    IsAThere__Fv
    IsBThere__Fv
    OSGetStackPointer
    OSReport
    SD2Var
    SDVar
    __dl__FPv
    _ctors
    _dtors
    _restgpr_27
    _savegpr_27
    count__1A
    OSLink
    OSUnlink
}