@echo off

REM Path to the Layout Binary Converter
set LYTCVTR=%NW4R_ROOT%\CommandLineTools\bin\nw4r_lytcvtr.exe
REM Major version of the Layout Binary Converter
set LYTCVTRVER=2
REM Banner mode option for the Layout Binary Converter
set LYTCVTRBNROPT=--banner

REM Determine which line of the Layout Binary Converter's output contains
REM version information, and extract the major version value.
for /F "skip=1 tokens=1,2" %%i in ('%LYTCVTR% 2^> nul') do if "%%i"  == "Version" for /F "delims=." %%k in ("%%j") do set LYTCVTRVER=%%k

REM Clear the banner mode option when the major version is zero
if "%LYTCVTRVER%" == "0" set LYTCVTRBNROPT=

IF EXIST arc rmdir /s /q arc
mkdir arc

REM If the outside keyframe segment setting is set as "repeat," the --bake-infinity option is required.
%LYTCVTR% -g --bake-infinity %LYTCVTRBNROPT% banner\layout arc

REM If the layout binary converter fails, the process is stopped.
if errorlevel 1 goto error

IF EXIST arc\fnta rmdir /s /q arc\fnta
%REVOLUTION_SDK_ROOT%\X86\bin\darch.exe -c arc banner.arc

if errorlevel 1 goto error

rmdir /s /q arc

mkdir arc

%LYTCVTR% %LYTCVTRBNROPT% icon\layout arc

REM If the layout binary converter fails, the process is stopped.
if errorlevel 1 goto error

IF EXIST arc\fnta rmdir /s /q arc\fnta
%REVOLUTION_SDK_ROOT%\X86\bin\darch.exe -c arc icon.arc

if errorlevel 1 goto error

rmdir /s /q arc
%REVOLUTION_SDK_ROOT%\X86\bin\WiiMakeBanner.exe -j banner.cfg.txt -o opening.bnr

if errorlevel 1 goto error

goto end

:error
echo Failed
pause
goto end

:end