@echo off

if "%1" == "" goto help
if "%NDEV%" NEQ "" goto NDEV

echo NDEV is not found. Do nothing and exit.
goto end

:help
echo usage: setsmem2size 64
echo usage: setsmem2size 128
echo  Sets console simulated MEM2 size. Either 64MB or 128MB is set as the console simulated memory size.
goto end

:NDEV
	echo NDEV detected

	if "%1" == "64" (
		goto NDEVSET64
	)

	if "%1" == "128" (
		goto NDEVSET128
	)

	if "%1" == "0x4000000" (
		goto NDEVSET64
	)

	if "%1" == "0x8000000" (
		goto NDEVSET128
	)

	if "%1" == "0" (
		goto NDEVSET0
	)

	if "%1" == "0x0" (
		goto NDEVSET0
	)

	echo usage: setsmem2size 64
	echo usage: setsmem2size 128
	echo  Sets console simulated MEM2 size. Either 64MB or 128MB is set as the console simulated memory size.
	goto end

:NDEVSET64
	%REVOLUTION_SDK_ROOT%\x86\bin\tickleBI2 -o %REVOLUTION_SDK_ROOT%\x86\bin\bi2.bin 44 0x4000000
	if errorlevel 1 goto NDEVFAILED
	echo Successfully done. Set 64MB as the console simulated mem size.
	goto NDEVDONE

:NDEVSET128
	%REVOLUTION_SDK_ROOT%\x86\bin\tickleBI2 -o %REVOLUTION_SDK_ROOT%\x86\bin\bi2.bin 44 0x8000000
	if errorlevel 1 goto NDEVFAILED
	echo Successfully done. Set 128MB as the console simulated mem size.
	goto NDEVDONE

:NDEVSET0
	%REVOLUTION_SDK_ROOT%\x86\bin\tickleBI2 -o %REVOLUTION_SDK_ROOT%\x86\bin\bi2.bin 44 0x0
	if errorlevel 1 goto NDEVFAILED
	echo Successfully done. Physical memory size is considered as the console simulated mem size.
	goto NDEVDONE

:NDEVDONE
	goto end

:NDEVFAILED
	echo Failed to set the console simulated mem size.
	goto end

:ENDWARNING

echo **********************************************************************
echo * If you make master data, you must execute ndrun before you do so!! *
echo **********************************************************************

:end